blob: 70a1bfd4432735e98d9070e73f470fc359672351 (
plain) (
blame)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
|
Program ::= Statement+
Statement ::= (AssignmentStatement | ImportDeclaration | ExternDeclaration | FunctionCallStatement | IfStatement | WhileStatement | ReturnStatement) SEMICOLON
AssignmentStatement ::= ("let")? ("*")? Expression EQUALS Expression
ImportDeclaration ::= "import" STRING
ExternDeclaration ::= "extern" IDENTIFIER EQUALS Type
FunctionCallStatement ::= (IDENTIFIER | FunctionDefinition) LPAREN FunctionArguments? RPAREN
IfStatement ::= "if" Expression LBRACE Statement* RBRACE -- TODO: Should function definitions be allowed?
WhileStatement ::= "while" Expression LBRACE Statement* RBRACE
ReturnStatement ::= RETURN Expression
FunctionArguments ::= Expression ("," Expression)*
Expression ::= EqualityExpression | AdditiveExpression
EqualityExpression ::= AdditiveExpression ("==" | "<" | ">") AdditiveExpression
AdditiveExpression ::= MultiplicativeExpression (("+" | "-") MultiplicativeExpression)*
MultiplicativeExpression ::= UnaryExpression (("*" | "/" | "%") UnaryExpression)*
UnaryExpression ::= ("!" | "-" | "*") UnaryExpression | PrimaryExpression
PrimaryExpression ::= NUMBER | BOOLEAN | CHAR | STRING | IDENTIFIER | FunctionCallStatement | FunctionDefinition | LPAREN Expression RPAREN
FunctionDefinition ::= LPAREN FunctionParameters? RPAREN ARROW IDENTIFIER LBRACE Statement* ReturnStatement SEMICOLON RBRACE
FunctionParameters ::= IDENTIFIER ":" Type ("," IDENTIFIER ":" Type)*
Type ::= IDENTIFIER | FunctionType
FunctionType ::= LPAREN (Type ("," Type)*)? RPAREN ARROW Type
ParameterTypes ::= Type ("," Type)*
|
